byFlasher

package com.byflasher.utils
{
 
	import flash.display.Sprite;
 
	/**
	 * @author	Maxim Sidorkin aka hitab
	 * @site	http://byflasher.com/
	 */
	public class Mask extends Sprite
	{
		private var _screen:Sprite;
		private var _x:Number;
		private var _y:Number;
		private var _width:Number;
		private var _height:Number;
 
		/**
		 * _screen - MovieClip или Sprite, для которого будет применена маска
		 * _width - ширина маски, если не установлена, то будет использована _screen.width (однако надо быть увереным, что _screen не пуст!)
		 * _height - высота маски, если не установлена будет использована _screen.height
		 * _x - положение макси по x
		 * _y - положение маски по y
		 */
		public function Mask(_screen:Sprite,  _width:Number = 0, _height:Number = 0, _x:Number = 0, _y:Number = 0)
		{
 
			this._screen = _screen;
			this._width = _width;
			this._height = _height;
			this._x = _x;
			this._y = _y;
 
			addMask();
		}
 
		private function addMask():void
		{
			/*
			 * Убедитесь, что _screen.width и _screen.height не раны 0
			 *
			 */
			_width  = _width  == 0 	? _screen.width  : _width;
			_height = _height == 0 	? _screen.height : _height;
 
			/*
			 * Рисуем черыхугольник для маски
			 */
			graphics.beginFill(0x000000, 1);
			graphics.drawRect(_x, _y, _width, _height);
 
			/*
			 * Добавляем маску в список отображения(при скэйлинге маска тоже будет скэйлится) и устанавливаем маску
			 */
			_screen.addChild(this);
			_screen.mask = this;
 
		}
 
	}
 
}

			/*
			 * Создаем маску, которая будет скрывать все,
			 * что находится за пределами сцены
			 *
			 */
			new Mask(this, 640, 480);

package com.byflasher.utils 
{
 
        import flash.display.Sprite;
 
        /**
         * @author      Maxim Sidorkin aka hitab
         * @site        http://byflasher.com/
         */
        public class Mask1 extends Sprite
        {
 
                // На сколько будут выпирать границы прямоугольников
                private const RECT_SIZE:int = 300;
 
                /**
                 * _screen - MovieClip или Sprite, для которого будет применена маска
                 * _width - ширина маски, если не установлена, то будет использована _screen.width (однако надо быть увереным, что _screen не пуст!)
                 * _height - высота маски, если не установлена будет использована _screen.height
                 * _color - цвет четырехугольников, по дефолту белый
                 * _x - положение макси по x
                 * _y - положение маски по y 
                 */
                public function Mask1(_screen:Sprite,  _width:Number = 0, _height:Number = 0, _color:uint = 0xFFFFFF, _x:Number = 0, _y:Number = 0) 
                {
 
                        addRectanglesOutStage(_screen, _width, _height, _color, _x, _y);
                }
 
                private function addRectanglesOutStage(_screen:Sprite,  _width:Number, _height:Number, _color:uint, _x:Number, _y:Number):void
                {
                        graphics.beginFill(_color, 1);
 
                        /*
                         * Рисуем верхний черыхугольник
                         */
                        graphics.drawRect(_x - RECT_SIZE, _y - RECT_SIZE, 2 * RECT_SIZE + _width, RECT_SIZE);
 
                        /*
                         * Рисуем левый черыхугольник
                         */
                        graphics.drawRect(_x - RECT_SIZE, _y, RECT_SIZE, _height);
 
                        /*
                         * Рисуем правый черыхугольник
                         */
                        graphics.drawRect(_x + _width, _y, RECT_SIZE, _height);
 
                        /*
                         * Рисуем нижний черыхугольник
                         */
                        graphics.drawRect(_x - RECT_SIZE, _y + _height, 2 * RECT_SIZE + _width, RECT_SIZE);
 
 
                        graphics.endFill();
                        cacheAsBitmap = true;
 
                        _screen.parent.addChild(this);
 
                }
 
        }
 
}